home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).zip
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A).po
/
SPEED.CONTROL.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
1KB
|
21 lines
10 REM PROGRAM SPEED.CONTROL
20 REM SET THE IIGS SPEED FROM APPLESOFT
30 REM DANGER..THE SPEED REGISTER C036..49206 IS SHARED BY
40 REM SHADOWING, DISK MOTOR CONTROL AND SYSTEM FUNCTIONS
50 REM HIGH BIT IS SPEED, 0=NORMAL 1=FAST
60 REM THIS ROUTINE USES BIT.BREAKER AND REASSEMBLER TO MODIFY
70 REM THE SPEED REGISTER WITHOUT CHANGING THE OTHER FUNCTIONS
80 BV = PEEK(49206): REM GET SPEED REGISTER VALUE
90 FOR BT = 0 TO 7:B(BT) = (BV - INT(BV/2) *2):BV = INT(BV/2): NEXT
100 HOME : PRINT "THE CURRENT SPEED IS ";: IF B(7) = 1 THEN PRINT "FAST": GOTO 120
110 PRINT "NORMAL"
120 PRINT : PRINT "COUNTING FROM 1 TO 1000 IN ";: IF B(7) = 1 THEN PRINT "FAST SPEED": GOTO 140
130 PRINT "NORMAL SPEED"
140 PRINT : FOR X = 1 TO 1000: PRINT X;: NEXT
150 REM CHANGE ONLY THE HIGH BIT
160 IF B(7) = 1 THEN B(7) = 0: GOTO 190
170 IF B(7) = 0 THEN B(7) = 1
180 REM REASSEMBLE THE REGISTER BITS INTO DECIMAL VALUE
190 V = B(0) +2 *B(1) +4 *B(2) +8 *B(3) +16 *B(4) +32 *B(5) +64 *B(6) +128 *B(7)
200 POKE 49206,V: REM CHANGE SPEED
210 GOTO 80